rem # https://docs.microsoft.com/zh-tw/windows-hardware/manufacture/desktop/configure-uefigpt-based-hard-drive-partitions
rem # https://learn.microsoft.com/zh-tw/windows-hardware/manufacture/desktop/configure-biosmbr-based-hard-drive-partitions?view=windows-11
rem == 2024-12-18 02:48:04
rem <<	 DiskPart /s B:\CreatePartitions-BIOS_AnyDiskSize.txt 	>>

rem == CreatePartitions-BIOS.txt ==
rem == These commands are used with DiskPart to


rem    create three partitions
rem    for a BIOS/MBR-based computer.
rem    Adjust the partition sizes to fill the drive
rem    as necessary. ==

rem ## select disk N0123
rem ## clean


rem == 1. System partition ======================
rem #- create partition primary size=100
create partition primary size=2048

format quick fs=fat32 label="System"
assign letter="S"
rem #- active


rem == 2. Windows partition =====================
rem ==    a. Create the Windows partition =======
create partition primary
rem ==    b. Create space for the recovery tools  
rem       ** Update this size to match the size of
rem          the recovery tools (winre.wim)
rem          plus some free space.
rem #- shrink minimum=500
rem ==    c. Prepare the Windows partition ====== 
format quick fs=ntfs label="Windows"
assign letter="W"

active
shrink desired=33793


rem == 3. Recovery partition ====================
create partition primary size = 1024
format quick fs=ntfs label="Recovery image"
assign letter="R"
set id=27


rem == 4. Restore partition ====================
create partition extended size = 32769
create partition logical size = 32768
format quick fs=ntfs label="Restore"
assign letter="T"


list volume

exit